Читать онлайн «XSLT». Страница 62

<xsl:template match="PLANET">

 <DATA>

  <NAME>

   <xsl:value-of select="descendant::NAME"/>

  </NAME>

  <MASS>

   <xsl:value-of select="descendant::MASS"/>

  </MASS>

  <DAY>

   <xsl:value-of select="descendant::DAY"/>

  </DAY>

 </DATA>

</xsl:template>

В этой главе мы рассмотрим все перечисленные оси. В данном примере осью является descendant, а имена элементов NAME, MASS и DAY — это условия узлов.

При создании образцов в качестве условий узлов (node test) можно использовать имена узлов или символ подстановки * для выбора любого узла элемента. Например, выражение child::*/child::NAME выбирает все элементы <NAME>, являющиеся правнуками контекстного узла. В XPath кроме имен и символа подстановки можно также применять, как и в образцах выбора, следующие условия узлов:

• условие узла comment() выбирает узлы комментария;

• условие узла node() выбирает узел любого типа;

• условие узла processing-instruction() выбирает узел инструкции обработки. В скобках можно указать название выбираемой инструкции обработки;

• условие узла text() выбирает текстовый узел

Например, в листинге 7.2 таблица стилей находит в документе все комментарии при помощи условия узла comment() и создает для каждого комментария новый, <!--Warning:comment found!--> (Внимание! Найден комментарий!).

Листинг 7.2. Выбор комментариев

<?xml version="1.0"?>

<xsl:stylesheet version="1.0"

 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

 <xsl:output method="xml"/>

 <xsl:template match="/">

  <xsl:for-each select="descendant::comment()">

   <xsl:comment>Warning: comment found!</xsl:comment>

  </xsl:for-each>

 </xsl:template>

</xsl:stylesheet>

При применении этой таблицы стилей к planets.xml получается следующий документ:

<?xml version="1.0" encoding="UTF-8"?>

<!--Warning: comment found!-->

<!--Warning: comment found!-->

<!--Warning: comment found!-->

Предикат в шаге расположения XPath сам содержит заключенное в скобки выражение XPath, которое вычисляется в истину или ложь. Когда результатом вычисления выражения является строка, XPath считает ее истиной, если строка не пуста. Когда результат — набор узлов, XPath считает его истиной, если он не пуст. Когда результат — число, то общий результат будет считаться истиной, если это число совпадает с контекстной позицией — например, PLANET[3] будет истиной тогда и только тогда, когда истиной будет PLANET[position()=3].

Предикаты содержат выражения XPath наподобие тех, которые встречались нам на протяжении этой главы: редко когда выражение возвращает набор узлов, главным образом возвращаются строки, числа или логические значения. Например, путь расположения preceding-sibling::MASS[position()*4] выбирает четыре предыдущих элемента-брата <MASS> для контекстного узла.

К этому моменту мы рассмотрели три части шагов расположения — ось, условие узла и предикат. Вы должны быть знакомы с этими элементами по проделанной нами работе с образцами выбора, но обратите внимание на ось в предыдущем примере — preceding-sibling. До сих пор мы видели только оси, выбиравшие образцы XSLT — оси child и attribute; теперь же мы рассмотрим новые оси, возможные в полных выражениях XPath, и начнем с оси ancestor.

Ось ancestor (предок) содержит всех предков контекстного узла, включая родителей, дедушек, прадедушек и т.д. Эта ось всегда содержит корневой узел — если только контекстным узлом не является сам корневой узел.

Взгляните на листинг 7.3, в котором при помощи оси ancestor осуществляется поиск имен (хранимых в элементе <NAME>) всех предков элементов <MASS>.

Листинг 7.3. Применение оси ancestor

<?xml version="1.0"?>

<xsl:stylesheet version="1.0"

 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

 <xsl:output method="xml"/>

 <xsl:template match="MASS">

  <xsl:for-each select="ancestor::*">

   <xsl:value-of select="./NAME"/>

  </xsl:for-each>

 </xsl:template>

 <xsl:template match="PLANET">

  <xsl:apply-templates select="MASS"/>

 </xsl:template>

</xsl:stylesheet>

Вот результат применения этой таблицы стилей к planets.xml:

<?xml version="1.0" encoding="utf-8"?>

Mercury

Venus

Earth

Ось ancestor-or-self содержит всех предков контекстного узла, а также сам контекстный узел. Это означает, помимо прочего, что такая ось всегда содержит корневой узел.

В листинге 7.4 добавлены атрибуты AUTHOR со значением «Steve» в весь документ.

Листинг 7.4. planets.xml с атрибутами AUTHOR

<?xml version=1.0"?>

<?xml-stylesheet type="text/xml" href="planets.xsl"?>

<PLANETS AUTHOR="Steve" >

 <PLANET AUTHOR="Steve" >

  <NAME>Mercury</NAME>

  <MASS AUTHOR="Steve" UNITS="(Earth = 1)">.0553</MASS>

  <DAY UNITS="days">58.65</DAY>

  <RADIUS UNITS="miles">1516</RADIUS>

  <DENSITY UNITS="(Earth = 1)">.983</DENSITY>

  <DISTANCE UNITS="million miles">43.4</DISTANCE><!--B перигелии-->

 </PLANET>

 <PLANET AUTHOR="Steve">

  <NAME>Venus</NAME>

  <MASS UNITS="(Earth = 1)">.815</MASS>

  <DAY UNITS="days">116.75</DAY>

  <RADIUS UNITS="miles">3716</RADIUS>

  <DENSITY UNITS="(Earth = 1)">.943</DENSITY>

  <DISTANCE UNITS="million miles">66.8</DISTANCE><!--В перигелии-->

 </PLANET>

 <PLANET>

  <NAME>Earth</NAME>

  <MASS UNITS="(Earth = 1)">1</MASS>

  <DAY UNITS="days">1</DAY>

  <RADIUS UNITS="miles">2107</RADIUS>

  <DENSITY UNITS="(Earth = 1)">1</DENSITY>

  <DISTANCE UNITS="million miles">128.4</DISTANCE><!--B перигелии-->

 </PLANET>

</PLANETS>

Предположим теперь, что я хочу перечислить по имени всех предков элементов <MASS>, имеющих атрибут AUTHOR, а также текущий элемент <MASS>, если у него есть атрибут AUTHOR. Это можно сделать при помощи оси ancestor-or-self и функции local-name (листинг 7.5).

Листинг 7.5. Применение оси ancestor-or-self

<?xml version="1.0"?>

<xsl:stylesheet version="1.0"

 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

 <xsl:output method="xml"/>

 <xsl:template match="MASS">

  <xsl:for-each select="ancestor-or-self::*[@AUTHOR]">

   <xsl:value-of select="local-name(.)"/>

   <xsl:text> </xsl:text>

  </xsl:for-each>

 </xsl:template>

 <xsl:template match="PLANET">

  <xsl:apply-templates select="MASS"/>

 </xsl:template>

</xsl:stylesheet>

Вот результат; показаны выбранные предки всех трех элементов <MASS>, включая сам элемент <MASS>, при условии, что у него имеется атрибут AUTHOR:

<?xml version="1.0" encoding="UTF-8"?>

PLANETS PLANET MASS

PLANETS PLANET

PLANETS

Ось descendant (потомок) содержит всех потомков контекстного узла. Заметьте, что сюда не входят атрибуты или узлы пространств имен, поскольку они не считаются дочерними узлами.

В следующем примере (листинг 7.6) демонстрируется работа с этой осью. На этот раз я хочу добавить примечание к элементу <PLANET> Меркурия: <INFO>Sorry, Mercury has blown up and is no longer available.</INFO> (Извините, но Меркурий взорвался и больше не доступен.). Чтобы найти Меркурий, мне достаточно только проверить, имеет ли какой-либо потомок элемента <PLANET> строковое значение «Mercury», что я сделаю при помощи выражения XPath внутри предиката выбора.

Листинг 7.6. Применение оси descendant

<?xml version="1.0"?>

<xsl:stylesheet version="1.0"

 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

 <xsl:output method="xml"/>

 <xsl:template match="PLANET[descendant::*='Mercury']">

  <xsl:copy>

   <xsl:apply-templates select="@*|node()"/>

   <INFO>Sorry. Mercury has blown up and is no longer available.</INFO>

  </xsl:copy>

 </xsl:template>

 <xsl:template match="@*|node()">

  <xsl:copy>

   <xsl:apply-templates select="@*|node()"/>

  </xsl:copy>

 </xsl:template>

</xsl:stylesheet>

Вот результирующий документ, дополненный новым элементом <INFO> только для Меркурия:

<?xml version="1.0" encoding="utf-8"?>

<?xml-stylesheet type="text/xml" href="planets.xsl"?>

<PLANETS>