Читать онлайн «Описание языка PascalABC.NET». Страница 25

Автоклассы

При описании класса перед словом class можно поставить слово auto. Такие классы называются автоклассами. Для автоклассов автоматически генерируется конструктор с параметрами, инициализирующими все поля класса, а также метод ToString, выводящий значения всех полей класса. Например:

type Person = auto class

name: string;

age: integer;

end;

var p := new Person('Иванов',20); // конструктор автокласса генерируется автоматически

writeln(p); // вызывается сгенерированный автоматически метод ToString

Здесь в отличие от действия writeln по умолчанию выводятся значения не только публичных, а всех полей.

Когда во время выполнения программы происходит ошибка, генерируется так называемое исключение, которое можно перехватить и обработать. Исключение представляет собой объект класса, производного от класса Exception, создающийся при возникновении исключительной ситуации.

Имеется ряд стандартных типов исключений. Можно также определять пользовательские типы исключений.

Если исключение не обработать, то программа завершится с ошибкой. Для обработки исключений используется оператор try ... except.

Обычно исключения возбуждаются в подпрограммах, поскольку разработчик подпрограммы, как правило, не знает, как обработать ошибочную ситуацию. В месте вызова подпрограммы уже, как правило, известно, каким образом следует обрабатывать исключение. Например, пусть разработана следующая функция:

function mymod(a,b: integer): integer;

begin

Result := a - (a div b) * b;

end;

Если вызвать mymod(1,0), то будет возбуждено исключение System.DivideByZeroException целочисленного деления на 0.

Рассмотрим наивную попытку обработать ошибочную ситуацию внутри функции mymod:

function mymod(a,b: integer): integer;

begin

if b = 0 then

writeln('Функция mymod: деление на 0');

Result := a - (a div b) * b;

end;

Подобное решение является плохим, поскольку программист, разрабатывающий функцию mymod, не знает, как она будет использоваться. Например, при вызове функции mymod в цикле мы увидим на экране многократное сообщение об ошибке.

Простейший способ - оставить исходный вариант функции и обрабатывать исключение System.DivideByZeroException:

try

readln(a,b);

writeln(mymod(a,b) mod (a-1));

...

except

on System.DivideByZeroException do

writeln('Деление на 0');

end;

Отличие от вывода внутри функции состоит в том, что при разработке программы мы сами определяем действие, которое необходимо выполнять при обработке исключения. Это может быть специфическое сообщение об ошибке, вывод в файл ошибок или пустой оператор (в случае, когда требуется беззвучно погасить исключение).

Однако, данное решение обладает существенным недостатком: исключение System.DivideByZeroException будет возбуждено и при a=1 и не будет связано с функцией mymod. Для устранения подобного недостатка определим собственный класс исключения и возбудим его в функции mymod:

type MyModErrorException = class(System.Exception) end;

function mymod(a,b: integer): integer;

begin

if b = 0 then

raise new MyModErrorException('Функция mymod: деление на 0');

Result := a - (a div b) * b;

end;

Тогда обработка ошибок будет выглядеть так:

try

readln(a,b);

writeln(mymod(a,b) mod (a-1));

...

except

on System.DivideByZeroException do

writeln('Деление на 0');

on e: MyModErrorException do

writeln(e.Message);

else writeln('какое-то другое исключение')

end;

Если сделать MyModErrorException наследником класса System.ArithmeticException, как и System.DivideByZeroException, то последний код можно упростить:

type MyModErrorException = class(System.ArithmeticException) end;

...

try

readln(a,b);

writeln(mymod(a,b) mod (a-1));

...

except

on e: System.ArithmeticException do

writeln(e.Message);

else writeln('Какое-то другое исключение')

end;

Наконец, можно поступить следующим образом. Перехватим в функции mymod исключение System.DivideByZeroException и в ответ сгенерируем новое - MyModErrorException:

function mymod(a,b: integer): integer;

begin

try

Result := a - (a div b) * b;

except

on e: System.DivideByZeroException do

raise new MyModErrorException('Функция mymod: деление на 0');

end;

end;

Все классы исключений являются потомками класса System.Exception, включающего следующий интерфейс:

type

Exception = class

public

constructor Create;

constructor Create(message: string);

property Message: string; // только на чтение

property StackTrace: string; // только на чтение

end;

Свойство Message возвращает сообщение, связанное с объектом исключения.

Свойство StackTrace возвращает стек вызовов подпрограмм на момент генерации исключения.

Ниже приводятся некоторые классы исключений, определенные в пространстве имен System и являющиеся производными от класса System.SystemException:

System.OutOfMemoryException - недостаточно памяти для выполнения программы;

System.StackOverflowException - переполнение стека (как правило, при многократных вложенных вызовах подпрограмм);

System.AccessViolationException - попытка доступа к защищенной памяти;

System.ArgumentException - неверное значение параметра подпрограммы;

System.ArithmeticException - базовый класс всех арифметических исключений. Наследники:

System.DivideByZeroException - целочисленное деление на 0;

System.OverflowException - переполнение при выполнении арифметической операции или преобразования типов;

System.FormatException - неверный формат параметра (например, при преобразовании строки в число);

System.IndexOutOfRangeException - выход за границы диапазона изменения индекса массива;

System.InvalidCastException - неверное приведение типов;

System.NullReferenceException - попытка вызвать метод для нулевого объекта или разыменовать нулевой указатель;

System.IO.IOException - ошибка ввода-вывода. Наследники:

System.IO.IOException.DirectoryNotFoundException - каталог не найден;

System.IO.IOException.EndOfStreamException - попытка чтения за концом потока;

System.IO.IOException.FileNotFoundException - файл не найден.

Для определения своего типа исключения достаточно породить класс - наследник класса Exception:

type MyException = class(Exception) end;

Тело класса-исключения может быть пустым, но, тем не менее, новое имя для типа исключения позволит его разграничить с остальными исключениями:

try

...

except

on MyException do

writeln('Целочисленное деление на 0');

on Exception do

writeln('Файл отсутствует');

end;

Исключение может содержать дополнительную информацию, связанную с точкой, в которой произошло исключение:

type

FileNotFoundException = class(Exception)

fname: string;

constructor Create(msg,fn: string);

begin

inherited Create(msg);

fname := fn;

end;

end;

...

procedure ReadFile(fname: string);

begin

if not FileExists(fname) then

raise new FileNotFoundException('Файл не найден',fname);

end;

...

try

...

except

on e: FileNotFoundException do

writeln('Файл '+e.fname+' не найден');

end;

Для повторной генерации исключения в блоке except служит оператор raise без параметров:

raise;

Например:

try

...

except

on FileNotFoundException do

begin

log.WriteLine('Файл не найден'); // запись в файл ошибок

raise;

end;

end;

Пример 1. Обработка неверного ввода данных.

Рассмотрим программу.

var i: integer;

begin

readln(i);

writeln(i);

writeln('Выполнение программы продолжается');

end.

Если при вводе данных произойдет ошибка (например, мы введем не число), то программа завершится с ошибкой (ошибка ввода), и последующие операторы writeln не будут выполнены.

Перехватим исключение в блоке try:

var i: integer;

begin

try

readln(i);

writeln(i);

except

writeln('Ошибка ввода');

end;

writeln('Выполнение программы продолжается');

end.

На этот раз при возникновении ошибки ввода программа не будет завершена, а выполнение будет передано в блок except, после чего выполнение программы продолжится дальше. Таким образом, в последней программе не выполнится лишь оператор writeln(i).